#!/usr/bin/perl

# Copyright 2007 Gérald Sédrati-Dinet
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# any later version.
# 
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# 
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

use strict;
use warnings;
use Sleepycat::DbXml 'simple';
use XML::Twig;
use LWP::UserAgent;
use Getopt::Long;

# Some files will be save under tree hierarchy based on executable location
use FindBin qw($Bin);
use lib "$Bin";

# Default values
my $path2DbEnv = "$Bin/dbxml";

# Parse command line options
Getopt::Long::Configure("bundling");
GetOptions(
  'path2dbenv|p=s' => \$path2DbEnv,
  'help|h'         =>
    sub {
      print STDERR <<USAGE;
Usage : $0 [-h] [-p <path_to_db_env>] <NameOfPolitician> <container>
where <NameOfPolitician> is the wiki name of the politician
and <container> can be candidates, mps, meps or ministers
(for convenience the final "s" can be omitted, also ".dbxml" can be appended)

Options can be:
  --path2dbenv, -p <path_to_db_env>: path to directory of DB XML database
                                     default: $Bin/dbxml
  --help, -h:                        print this message
USAGE
      exit 0;
    }
);

my $wiki_name = shift or die "You should provide the wiki name of the politician, see $0 -h\n";
my $theContainer = shift or die "You should provide the name of the container, see $0 -h\n";
$theContainer =~ s/s?(?:\.dbxml)?$/s/;

# Create a user agent object
my $ua = LWP::UserAgent->new;
$ua->agent("$0 (gibus perl script to fetch information from wiki.ffii.fr)");
my $headers = HTTP::Headers->new('Accept-Language' => 'fr');

# Fetch the wiki page
my $wiki_url = "http://wiki.ffii.fr/spikini/MemoirePolitique$wiki_name";
my $wiki_req = HTTP::Request->new(GET => $wiki_url, $headers);
my $wiki_res = $ua->request($wiki_req);
unless ($wiki_res->is_success) {
  die "Error fetching wiki page: $wiki_url: ", $wiki_res->status_line, "\n";
}
my $wiki_html = $wiki_res->content;
die "Unknown wiki page for $wiki_name\n" if $wiki_html =~ /Vous n'&ecirc;tes pas autoris&eacute; &agrave; lire cette page/o;

# Extract opinions
(my $opinions_str) = ($wiki_html =~ /<li class="spip"> <a href="http:\/\/www\.google\.fr\/search\?q=[^"]+" class="spip_out">Google<\/a><\/li><\/ul>(.+?)<!-- \/cached CACHE\/spikini\/\w+\.gz --><hr class="hr_clear" \/>\s*<\/div>\s*<div class="footer">/so);

die "No opinion has been entered for $wiki_name\n" unless $opinions_str;

my @opinions = split /<p class="spip"><img class='spip_puce' src='puce.gif' alt='-' \/>&nbsp;&nbsp;/o, $opinions_str;
shift @opinions;

eval {
  # Open a container in the db environment
  my $env = new DbEnv(0);
  $env->set_cachesize(0, 64 * 1024, 1);
  print "Opening $path2DbEnv/$theContainer.dbxml\n";
  $env->open($path2DbEnv, Db::DB_INIT_MPOOL|Db::DB_CREATE|Db::DB_INIT_LOCK|Db::DB_INIT_LOG);
  my $theMgr = new XmlManager($env);

  my $container = $theMgr->openContainer("$theContainer.dbxml");
  my $updateContext = $theMgr->createUpdateContext();

  # Get the document
  my $theDocument = $container->getDocument($wiki_name);
  my $docString = $theDocument->getContent();
  my $xml = XML::Twig->new(output_encoding=>'UTF-8',pretty_print => 'indented')->parse($docString);

  # Delete old opinions for XML tree
  my $opinions_elt = $xml->root->first_child('opinions') ? $xml->root->first_child('opinions') : $xml->root->insert_new_elt('last_child','opinions');
  $opinions_elt->cut_children;
  
  # Add opinions from wiki page into XML tree
  foreach my $opinion (@opinions) {
    $opinion =~ s/\s*$//gos;
    $opinion =~ s/&#8217;/'/go;
    $opinion =~ s/&nbsp;/ /go;
    $opinion =~ s/&#171; ?/"/go;
    $opinion =~ s/ ?&#187;/"/go;

    $opinion =~ s/^([\d\/]+) //os;
    my $date_opinion = $1;

    $opinion =~ s/^<a href="([^"]+)"[^>]*>([^<]+?)<\/a>(?:<\/p>)?\s*//os;
    my ($url_opinion, $title_opinion) = ($1, $2);

    $opinion =~ s/<a href="([^"]+)"[^>]*>([^<]+?)<\/a>/[$2->$1]/go;
    $opinion =~ s/<blockquote class="spip">\n<p class="spip">\n?(.+?)\n?<\/p><\/blockquote>/<quote>$1<\/quote>/gos;
    $opinion =~ s/<strong class="spip">(.+?)<\/strong>/{{$1}}/gos;
    $opinion =~ s/<p class="spip">//go;
    $opinion =~ s/<\/p>/\n/go;
    $opinion =~ s/^<br \/>/_ /gom;

    my $opinion_elt = $opinions_elt->insert_new_elt('last_child', 'opinion');
    $opinion_elt->insert_new_elt('last_child', 'date', $date_opinion);
    $opinion_elt->insert_new_elt('last_child', 'title', $title_opinion);
    $opinion_elt->insert_new_elt('last_child', 'url', $url_opinion);
    $opinion_elt->insert_new_elt('last_child', 'content', $opinion);
  }

  # Update document into database
  $docString = $xml->sprint;
  $theDocument->setContent( $docString );
  $container->updateDocument($theDocument, $updateContext);

  exit 0;
} ;

if (my $e = catch std::exception) {
  warn "Exception:\n";
  warn $e->what() . "\n";
  exit( -1 );
}
elsif ($@) {
  warn "Query failed\n";
  warn $@;
  exit( -1 );
}